/* Pipes.sl
   I Stephenson
   DCT Systems
   ian@dctsystems.co.uk
*/
#include "rmannotes.sl"


displacement
pipes(
	float Km = 4.0;
	float pipeDensity = 0.5;
	float levels = 3;
	
	float initialSFreq=8;
	float initialTFreq=8;
	float radius=0.1;
	
	float freqRatio = 1.432;
	
	float over=0;
	)
{
	float pipeHeight = 1.0; /*used to scale the w component with the s & t */
	float sfreq = initialSFreq;
	float tfreq = initialTFreq;

	float i;
	float magnitude;
	float ss, tt;
	
	point centerPoint=(0.5,0.5,0);
	point edgePoint  =(0,0,0);
	point testPoint  =(0  ,0,0);
	float distance;
	float tmp;

	magnitude= 0;
	for(i=0;i<levels;i+=1)
		{
		if(over!=0)
			{
			magnitude= 0;
			}
		ss = repeat(s, sfreq);
		tt = repeat(t, tfreq);
		
		setxcomp(testPoint,ss);
		setycomp(testPoint,tt);
	
		//*Left*/
		tmp = noise(whichtile(s,sfreq)-1+0.5,whichtile(t,tfreq)+0.5);
		if(tmp<pipeDensity)
			{
			setxcomp(edgePoint,0);
			setycomp(edgePoint,0.5);
			distance = ptlined(centerPoint,edgePoint,testPoint);
			if(distance<radius)
				magnitude =  max(magnitude,pipeHeight* sqrt(radius*radius-distance*distance));
			}
		
		/*Right*/
		tmp = noise(whichtile(s,sfreq)+0.5,whichtile(t,tfreq)+0.5);
		if(tmp<pipeDensity)
			{
			setxcomp(edgePoint,1.0);
			setycomp(edgePoint,0.5);
			distance = ptlined(centerPoint,edgePoint,testPoint);
			if(distance<radius)
				magnitude =
					max(magnitude,pipeHeight*sqrt(radius*radius-distance*distance));
			}
	
		/*Bottom*/
		tmp = noise(whichtile(s,sfreq)+0.5,whichtile(t,tfreq)-1+0.5);
		if(tmp<pipeDensity)
			{
			setxcomp(edgePoint,0.5);
			setycomp(edgePoint,0.0);
			distance = ptlined(centerPoint,edgePoint,testPoint);
			if(distance<radius)
				magnitude =  max(
					magnitude,pipeHeight*sqrt(radius*radius-distance*distance));
			}
		
		/*Top*/
		tmp = noise(whichtile(s,sfreq)+0.5,whichtile(t,tfreq)+0.5);
		if(tmp<pipeDensity)
			{
			setxcomp(edgePoint,0.5);
			setycomp(edgePoint,1.0);
			distance = ptlined(centerPoint,edgePoint,testPoint);
			if(distance<radius)
				magnitude =  max(
					magnitude,pipeHeight*sqrt(radius*radius-distance*distance));
			}
			
		/*
		tmp = noise(10000+whichtile(s,sfreq)+0.5,10000+whichtile(t,tfreq)+0.5);
		if(tmp <0.4)
			{
			distance = distance(centerPoint,testPoint);
			if(distance<radius)
				magnitude =  max(
					magnitude,sqrt(radius*radius-distance*distance));
			}
		else if( tmp <0.6)
				magnitude =  max(magnitude,pulse(0.4,0.6,0.05,ss)*
												pulse(0.4,0.6,0.05,tt));
		*/
		sfreq *= freqRatio;
		tfreq *= freqRatio;
		pipeHeight /= freqRatio;
		if(over!=0)
			{
			P -= normalize(N) * (magnitude) *Km;
			N  = calculatenormal(P);
			}
	}
	if(over==0)
		{
		P -= normalize(N) * (magnitude) *Km;
		N  = calculatenormal(P);
		}
}